#! /bin/sh
tr "\n" " " | tr ".Y" "\n" | sed -e "s/^ *//; s/  */ /g " |
awk '

# update minimum
function  upmin(x) { if (x<min) min=x }

# deletes everything on the line except numbers and spaces
# so that $1 becomes the first number, $2 the second, ..
function mknum() { gsub( "[^0-9 ]", "" );}

function debug(s) {
# comment out to hide debug
#print s
}
BEGIN {
	p = 0
	min = 0
	easy = 0
}
#{ print }
# we can tell apart the easy case by this
/Once upon/ { easy=1; $0=""}

# in, out
/^After/ ||
/newcomers/ ||
/jailed/ ||
/however/ ||
/^The driver/ ||
/summarized.*in.*out/ ||
0 { mknum(); p += $1; p -= $2; upmin($2); debug("in/out"); }
# out, in
/^At the next occ/ ||
/^Immediately/ ||
/summarized.*out.*in/ ||
/travellers jumped out/ ||
0 { mknum(); p -= $1; upmin(p); p += $2; debug("out/in"); }
# in
/^Another/ ||
/^As/ ||
/already/ ||
/unexpectedly/ ||
0 { mknum(); p += $1; debug("in");  }
# out
/^At the next stop/ ||
/emptied/ ||
0 { mknum(); p -= $1; debug("out");  }

# the end of a story
/^Finally/ {
	mknum();  p -= $1; upmin(p);
	if (easy) {
		if (min<0 || p!=0) print "NO"
		else print "YES"
	} else {
		if (min<p) print "NO"
		else print "YES"
	}
	p=0; min=0; easy=0;
}

# just to check we didnt miss anything

/(^NEW STO|IPSC|The scenery|^The land around|^It seemed|^It was)/ { debug("podmaz: " $0); $0 = ""}
/[^0-9 ]/ { print "Line left over:"; print }

# just another debug
#{print p}
'
# vim: set sw=4 sts=4 noet  ft=awk :